Este artigo pode te ajudar muito se você recebe muitos emails ou que possui muitos emails em sua caixa de entrada e deseja organizar os emails mas não sabe por onde começar, aprenda como carregar e-mails do outlook para o excel.
Esta postagem foi revisada onde foram incluídos os seguintes itens no código:
Cells(r, "G") = olItem.LastModificationTime 'Última modificação Cells(r, "H") = olItem.Categories 'Categoria Cells(r, "I") = olItem.SenderName 'Nome do remetente Cells(r, "J") = olItem.FlagRequest 'Acompanhamento
De tempos em tempos dou uma boa organizada em meu outlook revendo a estrutura de pastas, tarefas, agenda e emails e esta semana estava no escritório e achei que esta deveria ser a hora de fazer isso novamente, porém isso é uma tarefa que leva tempo e como sou um pouco chato com estas coisas de organização, não gosto de apenas jogar os emails em uma pasta de arquivo morto e pronto, acho que tudo tem de ter o seu lugar.
Como qualquer coisa na vida ou projeto que vamos fazer temos de ter dimensão do tamanho deste para que assim possamos ter um norte de por onde devemos partir e o que fazer, porém isso tudo é muito massante, desgastante e acaba sendo um pouco trabalhoso.
O código abaixo vai lhe ajudar a listar no Microsoft Excel os emails do seu arquivo PST linha após linha, email, data, remetente e anexos.
Este código tem um pedaço de uma rotina que encontrei no StackOverflow e em um fórum de Access…
Preciso verificar meu histórico do celular pois foi via mobile que encontrei, após isso colocarei o link com o crédito.
O código faz referencia ao Microsoft Outlook ‘GetObject(, “Outlook.Application”)’ onde ele define os objetos, faz a verificação se o objeto existe e se caso não existir cria o objeto ‘CreateObject(“Outlook.Application”)’
Após exportar os dados para o Excel, basta fazer uma Tabela Dinâmica e visualizar os dados como desejar.
Carregar e-mails do outlook para o excel:
Sub Emails_Outlook()
'Carregar e-mails do outlook para o excel
Dim appOutlook As Object
Dim olNS As Object
Dim olFolder As Object
Dim olItem As Object
Dim r As Long
On Error Resume Next
Set appOutlook = GetObject(, "Outlook.Application")
If appOutlook Is Nothing Then
Set appOutlook = CreateObject("Outlook.Application")
End If
On Error GoTo 0
Set olNS = appOutlook.GetNamespace("MAPI")
'Abaixo preencha o nome do arquivo de dados PST e a pasta.
'Neste caso o arquivo é Douglas Godoy e a pasta Caixa de Entrada.
Set olFolder = olNS.Folders("Douglas Godoy").Folders("Caixa de Entrada")
Cells.Delete
r = 3
'Cria um array montando o título das colunas no arquivo.
Range("A3:K3") = Array("Título", "Quem enviou", "Para", "Data e Hora", "Anexos", "Tamanho","Última modificação","Categoria","Nome do Remetente","Tipo de acompanhamento","Conteúdo")
For Each olItem In olFolder.Items
If TypeName(olItem) = "MailItem" Then
r = r + 1
Cells(r, "A") = olItem.Subject 'Assunto do e-mail
Cells(r, "B") = olItem.SenderEmailAddress 'E-mail do remetente
Cells(r, "C") = olItem.To 'E-mail do destinatário
Cells(r, "D") = olItem.ReceivedTime 'Data/Hora de recebimento
Cells(r, "E") = olItem.Attachments.Count 'Número de anexos
Cells(r, "F") = olItem.Size 'Tamanho da mensagem em bytes
Cells(r, "G") = olItem.LastModificationTime 'Última modificação
Cells(r, "H") = olItem.Categories 'Categoria
Cells(r, "I") = olItem.SenderName 'Nome do remetente
Cells(r, "J") = olItem.FlagRequest 'Acompanhamento
'Cells(r, "K") = olItem.Body 'Tome cuidado ao utilizar pois carrega os dados do corpo do email
Application.StatusBar = r
End If
Next olItem
Columns.AutoFit
End Sub
Observação: caso você não saiba qual o nome do seu arquivo de dados do Outlook, acesse:
Ferramenta Outlook – Menu Ferramentas – Configurações de Conta – Aba Arquivo de Dados.
O nome que consta na aba “Arquivo de dados que deve ser inserido em olNS.Folders(“Douglas Godoy”).
Espero desta forma ter lhe ajudado a buscar seus emails em sua caixa de entrada, desta forma fica muito mais fácil saber por onde começar a organizar seus emails e o qual a situação atual do seu arquivo de dados.
Caso você conheça alguma outra forma Carregar e-mails do outlook para o excel, compartilhe, sua opinião é muito importante.
DICA:
Caso você queira aprender como listar todas tabelas dinamicas do seu arquivo em excel, deixo o artigo abaixo como dica!
Como Listar todas tabelas dinâmicas do seu arquivo Excel com VBA
Agradeço pela leitura e fico no aguardo de seus comentários e sugestões.
Um abraço. DG
Deixe um comentário